纪小年

;****************************步进电机的驱动*************************************
;FOSC = 12MHz
;---------------------------------------------------------------------------------
; 步进电机的驱动信号必须为脉冲信号!!! 转动的速度和脉冲的频率成正比!!!
; 本步进电机步进角为 5.625度 . 一圈 360 度 , 需要64个脉冲完成!!!
;---------------------------------------------------------------------------------
; A组线圈对应 P2.4
; B组线圈对应 P2.5
; C组线圈对应 P2.6
; D组线圈对应 P2.7
; 正转次序: AB组--BC组--CD组--DA组 (即一个脉冲,正转5.625度)
;----------------------------------------------------------------------------------
ORG 0000H
	LJMP	MAIN
ORG 0100H
 
MAIN:
;----------------------------正转--------------------------
	MOV	R3,#192		;正转3圈共192个脉冲
START:
	MOV	R0,#00H
START1:
	MOV	P2,#00H
	MOV	A,R0
	MOV	DPTR,#TABLE
	MOVC	A,@A+DPTR
	JZ	START		;对A的判断,当A=0时则转到 START
	MOV	P2,A
	LCALL	DELAY
	INC	R0
	DJNZ	R3,START1
	MOV	P2,#00H
	LCALL	DELAY1
;-----------------------------反转------------------------
	MOV	R3,#64		;反转一圈共64个脉冲
START2:
	MOV	P2,#00H
	MOV	R0,#05
START3:
	MOV	A,R0
	MOV	DPTR,#TABLE
	MOVC	A,@A+DPTR
	JZ	START2
	MOV	P2,A
	CALL	DELAY
	INC	R0
	DJNZ	R3,START3
	MOV	P2,#00H
	LCALL	DELAY1
	LJMP MAIN
;---------------------------转速控制-----------------------
DELAY:	MOV	R7,#40		;步进电机的转速
M3:	MOV	R6,#248
	DJNZ	R6,$
	DJNZ	R7,M3
	RET
;---------------------------延时控制----------------------
DELAY1: 	MOV	R4,#20	;2S 延时子程序
DEL2: 	MOV	R3,#200
DEL3:	MOV	R2,#250
	DJNZ	R2,$
	DJNZ	R3,DEL3
	DJNZ	R4,DEL2
	RET
;---------------------------正反转表----------------------
TABLE:
	DB	30H,60H,0C0H,90H;  正转表
	DB	00;  正转结束
	DB	30H,90H,0C0H,60H;  反转表
	DB	00;  反转结束
END